SUTO6100_Fire Extension

No preview image

1 collaborator

ACKNOWLEDGMENT

This model is from Chapter Three of the book "Introduction to Agent-Based Modeling: Modeling Natural, Social and Engineered Complex Systems with NetLogo", by Uri Wilensky & William Rand.

Wilensky, U. & Rand, W. (2015). Introduction to Agent-Based Modeling: Modeling Natural, Social and Engineered Complex Systems with NetLogo. Cambridge, MA. MIT Press.

This model is in the IABM Textbook folder of the NetLogo Models Library. The model, as well as any updates to the model, can also be found on the textbook website: http://www.intro-to-abm.com/.

WHAT IS IT?

This project simulates the spread of a fire through a forest. It shows that the fire's chance of reaching the right edge of the forest depends critically on the density of trees. This is an example of a common feature of complex systems, the presence of a non-linear threshold or critical parameter. This model extends the Fire Simple Extension 2 model by adding BIG-JUMPS.

HOW IT WORKS

The fire starts on the left edge of the forest, and spreads to neighboring trees. The fire spreads in four directions: north, east, south, and west.

Unlike the first few Fire models, this adds long distance transmission of fire, which means that fire can jump across unburnt stretches of forest.

HOW TO USE IT

Click the SETUP button to set up the trees (green) and fire (red on the left-hand side).

Click the GO button to start the simulation.

The DENSITY slider controls the density of trees in the forest. (Note: Changes in the DENSITY slider do not take effect until the next SETUP.)

The PROBABILITY-OF-SPREAD slider affects how the fire spreads from patch to patch.

The SOUTH-WIND-SPEED slider affects how strong the wind is from the south. You can set it negative to create a north wind.

The WEST-WIND-SPEED slider affects how strong the wind is from the south. You can set it negative to create a east wind.

The BIG-JUMPS? switch controls whether or not sparks can jump across long distances.

THINGS TO NOTICE

Compare this model to the Fire Simple Extension 2 model. How do the sparks affect the results?

Does adding spark jumping change the overall amount of forest burned? Why do you think that might be?

THINGS TO TRY

Try running the same settings with BIG-JUMPS? turned off and on, how does this affect the results?

RELATED MODELS

Fire Simple, Fire, Percolation, Rumor Mill

CREDITS AND REFERENCES

This model is a simplified version of:

Wilensky, U. (1997). NetLogo Fire model. http://ccl.northwestern.edu/netlogo/models/Fire. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

HOW TO CITE

This model is part of the textbook, “Introduction to Agent-Based Modeling: Modeling Natural, Social and Engineered Complex Systems with NetLogo.”

If you mention this model or the NetLogo software in a publication, we ask that you include the citations below.

For the model itself:

Wilensky, U. (2006). NetLogo Fire Simple Extension 3 model. http://ccl.northwestern.edu/netlogo/models/FireSimpleExtension3. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

Please cite the NetLogo software as:

Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

Please cite the textbook as:

Wilensky, U. & Rand, W. (2015). Introduction to Agent-Based Modeling: Modeling Natural, Social and Engineered Complex Systems with NetLogo. Cambridge, MA. MIT Press.

COPYRIGHT AND LICENSE

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals [
  initial-trees   ;; how many trees (green patches) we started with
]

to setup
  clear-all
  ;; make some green trees
  ask patches [
    if (random 100) < density
    [ set pcolor green ]
    ;; make a column of burning trees at the left-edge
    if pxcor = min-pxcor
    [ set pcolor red ]
  ]
  ;; keep track of how many trees there are
  set initial-trees count patches with [pcolor = green]
  reset-ticks
end 

to go
  ;; stop the model when done
  if all? patches [pcolor != red]
      [ stop ]

  ;; each burning tree (red patch) checks its 4 neighbors.
  ;; If any are unburned trees (green patches), change their probability
  ;; of igniting based on the wind direction
  ask patches with [pcolor = red] [
    ;; ask the unburned trees neighboring the burning tree
    ask neighbors4 with [pcolor = green] [
      let probability probability-of-spread

      ;; compute the direction from you (the green tree) to the burning tree
      ;; (NOTE: “myself” is the burning tree (the red patch) that asked you
      ;; to execute commands)
      let direction towards myself

      ;; the burning tree is north of you
      ;; so the south wind impedes the fire spreading to you
      ;; so reduce the probability of spread
      if (direction = 0 ) [
        set probability probability - south-wind-speed ]

      ;; the burning tree is east of you
      ;; so the west wind impedes the fire spreading to you
      ;; so reduce the probability of spread
      if (direction = 90 ) [
        set probability probability - west-wind-speed ]

      ;; the burning tree is south of you
      ;; so the south wind aids the fire spreading to you
      ;; so increase the probability of spread
      if (direction = 180 ) [
        set probability probability + south-wind-speed ]

      ;; the burning tree is west of you
      ;; so the west wind aids the fire spreading to you
      ;; so increase the probability of spread
      if (direction = 270 ) [
        set probability probability + west-wind-speed ]
      if random 100 < probability [
        set pcolor red ;; to catch on fire
        ;; if big jumps is on, then sparks can fly farther
        if big-jumps? [
          let target patch-at (west-wind-speed / 5) (south-wind-speed / 5)
          if target != nobody and [ pcolor ] of target = green [
            ask target [
              set pcolor red ;; to ignite the target patch
            ]
          ]
        ]
      ]
    ]
    set pcolor red - 3.5;; once the tree is burned, darken its color
  ]

  tick   ;; advance the clock by one “tick”
end 


; Copyright 2006 Uri Wilensky.
; See Info tab for full copyright and license.

There is only one version of this model, created 17 days ago by Jalayer Khalilzadeh.

Attached files

No files

This model does not have any ancestors.

This model does not have any descendants.

NetLogo