Infectious disease outbreak-Mutation and Breakthrough

;;
;; This model is developed by Dr. Lin Xiang at the University of Kentucky. Contact: lin.xiang@uky.edu
;;
;; If you see this page rather than a "download" button when downloading the model, click the "download" icon
;; in your browser to download this model file.
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;



turtles-own [day transmissibility immunity infection mortality]
Patches-own [ ]
Globals [watching max-daily-cases Transmission-rate num-of-breakthrough current-mortality]

to-report average-transmission-rate
  report mean [transmissibility] of turtles with [color > 22 and color < 28]
end 

to setup
  clear-all
  setup-turtles
  setup-patches

  set watching false
  set num-of-breakthrough 0

  reset-ticks
end 

to setup-turtles
  create-turtles Population-size * (100 - vaccination-rate) * 0.01
  [set color 68
    set size 1.25
    set shape "person-1"
    set day 0
    set transmissibility 0
    set immunity 0
    set infection 0
    set mortality 0
    setxy random-xcor random-ycor
  ]

  create-turtles Population-size * (vaccination-rate * 0.01)
  [set color blue
    set size 1.25
    set shape "person-1"
    set day 0
    set transmissibility 0
    set immunity 50
    set infection 1
    set mortality 0
    setxy random-xcor random-ycor
  ]
end 

to setup-patches
  ask patches [set pcolor 0]
end 

to go

  if ticks >= Days [stop]
  move
  transmission
  sickness
  find-max-daily-cases
  tick
end 

to move
  ask turtles
  [right random 360 forward 1]
end 

to add-an-infected-person
  ask one-of turtles with [color = 68]
  [ set transmissibility Original-transmission-rate
    set immunity transmissibility
    set infection infection + 1
    set color (transmissibility + 444.5) / 19.8
    set mortality 10
    setxy random-xcor random-ycor
  ]
end 

to transmission
  ask turtles with [color > 22 and color < 28]
  [let susceptible-person one-of other turtles in-radius 1.5 with [color = 68]
    if susceptible-person != nobody
    [ set transmission-rate [transmissibility] of self
      set current-mortality [mortality] of self
      ask susceptible-person
      [ if random 100 < transmission-rate
        [ifelse Mutation? = true
          [ifelse random 100 < 25
              [set transmission-rate (1 + random 100)         ;transmissibility mutate randomly
               set infection infection + 1                    ;count the times being infected
               set transmissibility transmission-rate        ;set the mutated transmissibility
               set color (transmissibility + 444.5) / 19.8   ;set the color according to the transmissibility
               set immunity transmissibility]                 ;set the immunity level the same as the trasmissibility level
               ;set mortality (1 + random 20)]
              [set infection infection + 1
               set transmissibility transmission-rate
               set color (transmissibility + 444.5) / 19.8
               set immunity transmissibility
               set mortality current-mortality]]
          [set infection infection + 1
            set transmissibility transmission-rate
            set color (transmissibility + 444.5) / 19.8
            set immunity transmissibility
            set mortality current-mortality]]
        ]
      ]
    ]


  if Breakthrough-infection? = true              ;breakthrough
  [if count turtles with [color = blue] > 0
   [ask turtles with [color > 22 and color < 28]
   [let breakthrough-person one-of other turtles in-radius 1.5 with [color >= blue]
    if breakthrough-person != nobody
    [ set transmission-rate [transmissibility] of self
      set current-mortality [mortality] of self
      ask breakthrough-person
       [if random 1000 < (0.05 * abs ([immunity] of self - transmission-rate) + 2)   ; compare the imminuty level with the stain transmissibility to determine the probability of breakthrough (larger difference lead to more breakthrough. Plus 2 to represent there is no 100% vaccination protection.
        [if random 100 < transmission-rate
        [ifelse Mutation? = true
         [ifelse random 100 < 25
          [set transmission-rate (1 + random 100)
             set infection infection + 1
             set transmissibility transmission-rate
             set color (transmissibility + 444.5) / 19.8
             set immunity transmissibility
             ;set mortality (1 + random 20)
             set num-of-breakthrough num-of-breakthrough + 1]
          [set transmissibility transmission-rate
             set infection infection + 1
             set mortality current-mortality
             set color (transmissibility + 444.5) / 19.8
             set immunity transmissibility
             set num-of-breakthrough num-of-breakthrough + 1]]
         [set transmissibility transmission-rate
             set infection infection + 1
             set mortality current-mortality
             set color (transmissibility + 444.5) / 19.8
             set immunity transmissibility
             set num-of-breakthrough num-of-breakthrough + 1]]
        ]
      ]
     ]
    ]
   ]
  ]
end 

to sickness
  ask turtles with [color > 22 and color < 28]
  [set day day + 1
    if day >= 15
    [ifelse random 100 < 10
     [die]
     [ifelse infection <= 1  [set color blue ][set color 126]]
  ]
  ]
end 

to watch-an-infected-person
  watch one-of turtles with [color > 22 and color < 28]
end 

to find-max-daily-cases
  if count turtles with [color > 22 and color < 28] > max-daily-cases        ;Count the infectious.If it is greater than the current record of max daily cases
  [set max-daily-cases count turtles with [color > 22 and color < 28]]       ;update the max daily case
end