Infectious Disease Outbreak (COV-19)--Vaccination

;;
;; This model is developed by Dr. Lin Xiang at the University of Kentucky. Contact: lin.xiang@uky.edu
;;
;; If you see this page rather than a "download" button when downloading the model, click the "download" icon
;; in your browser to download this model file.
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


turtles-own [day infected susceptible]
Patches-own [ ]
Globals [watching LM max-daily-cases]

to setup
  clear-all
  setup-turtles
  setup-patches

  set watching false

  reset-ticks
end 

to setup-turtles
  create-turtles Population-size * (100 - vaccination-rate) * 0.01
  [set color 68
    set size 1.25
    set shape "person-1"
    set day 0
    set infected false
    set susceptible true
    setxy random-xcor random-ycor
  ]

  create-turtles Population-size * (vaccination-rate * 0.01)
  [set color blue
    set size 1.25
    set shape "person-1"
    set day 0
    set infected false
    set susceptible false
    setxy random-xcor random-ycor
  ]

  set LM 0
end 

to setup-patches
  ask patches [set pcolor 0]
end 

to go

  if ticks >= Days [stop]
  move
  transmission
  sickness
  find-max-daily-cases
  tick
end 

to move
  ask turtles
  [right random 360 forward 1]
end 

to add-an-infected-person
  create-turtles 1
  [set color orange
    set size 1.25
    set shape "person-1"
    set day 0
    set infected true
    set susceptible false
    setxy random-xcor random-ycor
  ]
end 

to transmission
  ask turtles with [infected = true]
  [
    let healthy-person one-of other turtles in-radius 1.5 with [susceptible = true]
    if healthy-person != nobody
    [ask healthy-person [
      if random 100 < Transmission-rate
      [set color orange set infected true set susceptible false ]]
    ]
    ]
end 

to sickness
  ask turtles with [infected = true]
  [set day day + 1
    if day >= 15
    [ifelse random 100 < mortality
      [set LM LM + 1 die  ]
      [set color blue
       set infected false
       set susceptible false ] ]
  ]
end 

to watch-an-infected-person
  watch one-of turtles with [infected = true]
end 

to find-max-daily-cases
  if count turtles with [infected = true ] > max-daily-cases        ;Count the infectious.If it is greater than the current record of max daily cases
  [set max-daily-cases count turtles with [infected = true ]]       ;update the max daily case
end