Infectious Disease Outbreak (COVID-19)-Basic Phenomenon

;;  |--------------------------------------------------------------------------------------------
;;  |Infectious Disease Outbreak-Basic Phenomenon
;;  |Dr. Lin Xiang (lin.xiang@uky.edu) created this module at the University of Kentucky in 2020.
;;  |If you mention this model in a publication, we ask that you include the citations below.
;;  |
;;  | Xiang, L. (2020). Infectious Disease Outbreak-Basic Phenomenon. Department of STEM Education, University of Kentucky, Lexington, KY.
;;  |--------------------------------------------------------------------------------------------
;;  |CREATIVE COMMONS LICENSE
;;  |This code is distributed by Lin Xiang under a Creative Commons License:
;;  |Attribution-ShareAlike 4.0 International (CC BY-SA 4.0)
;;  |https://creativecommons.org/licenses/by-sa/4.0/
;;  |--------------------------------------------------------------------------------------------

turtles-own [day]
Patches-own [ ]
Globals [LM max-daily-cases]

to setup
  clear-all
  setup-turtles
  setup-patches
  set LM 0
  reset-ticks
end 

to setup-turtles
  create-turtles Population-size
  [set color 68
    set size 1.25
    set shape "person"
    set day 0
    setxy random-xcor random-ycor
  ]
end 

to setup-patches
  ask patches [set pcolor 0]
end 

to go

  if ticks >= days [stop]
  move
  transmission
  sickness
  find-max-daily-cases
  tick
end 

to move
  ask turtles
  [right random 360 forward 1]
end 

to add-an-infected-person
  create-turtles 1
  [set color orange
    set size 1.25
    set shape "person"
    setxy random-xcor random-ycor
  ]
end 

to transmission
  ask turtles with [color = orange]
  [
    let healthy-person one-of other turtles in-radius 1 with [color = 68]
    if healthy-person != nobody
    [ask healthy-person [
      if random 100 < 90
      [set color orange]]]
  ]
end 

to sickness
  ask turtles with [color = orange]
  [set day day + 1
    if day >= 15
    [ifelse random 100 < 20
      [ set LM LM + 1 die  ]
      [set color blue] ]
  ]
end 

to watch-a-person
  watch one-of turtles with [color = orange]
end 

to find-max-daily-cases
  if count turtles with [color = orange ] > max-daily-cases        ;Count the infectious.If it is greater than the current record of max daily cases
  [set max-daily-cases count turtles with [color = orange ]]       ;update the max daily case
end