Pocket Mouse

turtles-own [energy]

to-report Time-period
  report ticks / 40
end 

to setup
  clear-all
  setup-turtles
  setup-patches
  reset-ticks
end 

to setup-turtles
  create-turtles Starting-population-size
  ask turtles [
    set color 37.7 - random-float (Mutation-rate / 2)
    set shape "mouse side"
    set size 1.25
    setxy random-xcor random-ycor
    set energy 20]
end 

to setup-patches
  ask patches [set pcolor Environment-color]
end 

to go

  if years = 0 [user-message "Number of years is needed" stop]
  if ticks > years * 40 [stop]


  if color-heritable? = false [ask turtles [set color 31 + random-float 7.5]]
  diff-survival
  move
  forage
  dead
  reproduce
  regrow
  if count turtles = 0 [user-message "All mice have died."  Stop]
  tick
end 

to move
  ask turtles [rt (random 180)
               fd 1
               set energy energy - 1]
end 

to dead
  ask turtles [if energy <= 0 [die]]
end 

to forage
  ask turtles [if pcolor = Environment-color [set energy (energy + 1.5) set pcolor pcolor - 1]]
end 

to reproduce
  ask turtles [
    if energy >= 40
    [hatch 1
      [set energy 20
       if random 100 < Mutation-rate [
          ;set color (color - 1) + random-float 2
          set color 31 + random-float 7.5
        ]
        if color < 31 [set color 31]
        if color > 38.5 [set color 38.5]]
      set energy energy - 20
      ] ]
end 

to regrow
  ask patches with [pcolor != Environment-color] [set pcolor Environment-color]
end 

to diff-survival
    ask turtles [
      if random 2500 < (abs (color - Environment-color) * Number-of-visual-predators * 0.5) [die]
    ]
end