Yet another implementation of Watts and Strogatz Small World Algorithm

to setup
  clear-all
  ;; creates all the nodes
  set-default-shape turtles "circle"
  create-turtles  nb-nodes  [set size 0.5 set color gray]
  ;; arrange them in a circle in order by who number
  layout-circle (sort turtles) radius
  ;; create the link between the nodes with the Watts and Strogatz algorithm
  link-nodes
  ;; set the simulation time to 0 (plot things)
  reset-ticks
;;  go
end 

;;to go
;;  tick
;;end


;; create the links among nodes (Watts and Strogatz algorithm), add weight and color

to link-nodes  
  ;; create a regular lattice
  ask turtles [
    let n 1
    while [ n <= K ]
    [
      ifelse who < (count turtles - K)
      [
        ifelse (random-float 1) < beta
        [
          random-link
        ]
        [
          normal-link n
        ]
      ]
      [
        normal-link n
      ]
      set n (n + 1)
    ]
  ]
end 

to normal-link [n]
  create-link-with turtle ((who + n) mod count turtles)
  [ 
    set color blue
  ]
end  

;; create a link with another 'not-yet linked' node whose id > caller id 

to random-link  
  let myid who
  let other-node one-of other turtles with [(who > myid) and (not link-neighbor? turtle myid)]
  if other-node != nobody
  [
    create-link-with other-node
    [
      set color red
    ]
  ]
end