Communication-T-T Example

turtles-own [
  message?      ;; true or false: has this turtle gotten the message yet?
]

to setup
  clear-all
  crt 500 [
    set message? false
    setxy random-xcor random-ycor
  ]
  ask one-of turtles [ set message? true ]   ;; give the message to one of the turtles
  ask turtles [ recolor ]
  reset-ticks
end 

to go
  ask turtles [ move ]
  ask turtles [ communicate ]
  ask turtles [ recolor ]
  tick
end 

;; move randomly

to move  ;; turtle procedure
  fd random 4
  ;; turn a random amount between -40 and 40 degrees,
  ;; keeping the average turn at 0
  rt random 40
  lt random 40
end 

;; the core procedure!

to communicate  ;; turtle procedure
  if any? other turtles-here with [message?]
    [ set message? true ]
end 

; color turtles with message red, and those without message blue

to recolor  ;; turtle procedure
  ifelse message?
    [ set color red ]
    [ set color blue ]
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.