Link Lattice Example

to setup-square
  clear-all
  ;; Create a turtle on each patch. A link always connects two
  ;; turtles, so we must make turtles first before we can make
  ;; links.
  ask patches [ sprout 1 ]
  ;; Now create the links. Note that some turtles will try to create
  ;; links that already exist because they were made by earlier
  ;; turtles. That's OK; the CREATE-LINKS-WITH command will skip
  ;; links that already exist.
  ask turtles [ create-links-with turtles-on neighbors4 ]
end 

to setup-hex
  clear-all
  ;; Create a turtle on each patch. A link always connects two
  ;; turtles, so we must make turtles first before we can make
  ;; links.
  ask patches [ sprout 1 ]
  ;; Now create the links.
  ask turtles [
    create-links-with turtles-at 0 1
    create-links-with turtles-at 1 0
    if pxcor mod 2 = 0 [
      create-links-with turtles-at  1 -1
      create-links-with turtles-at -1 -1
      ;; Move every other column of turtles down by half a patch,
      ;; resulting in a hexagonal pattern.
      set ycor ycor - 0.5
    ]
  ]
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.