Lattice-Walking Turtles Example

breed [nodes node]
breed [walkers walker]

walkers-own [location]  ;; holds a node

to setup
  clear-all
  set-default-shape nodes "hex"
  ;; create a hex grid of nodes
  ask patches
  [ sprout-nodes 1
    [ set color gray - 3.5 ;; dark gray
      set size 1.2
      ;; shift even columns down
      if pxcor mod 2 = 0
      [ set ycor ycor - 0.5 ] ] ]
  ;; connect the nodes to make a lattice
  ask nodes
  [ ifelse pxcor mod 2 = 0
      [ create-links-with nodes-on patches at-points [[0 1] [1 0] [1 -1]] ]
      [ create-links-with nodes-on patches at-points [[0 1] [1 1] [1 0]] ] ]
  ask links [ hide-link ]
  ;; put some "walker" turtles on the lattice
  create-walkers 20 [
    set color red
    set location one-of nodes
    move-to location
  ]
  reset-ticks
end 

to go
  ask walkers [
    set-location one-of [link-neighbors] of location
  ]
  tick
end 

to set-location [new-location]  ;; walker procedure
  set location new-location
  face new-location  ;; not strictly necessary, but improves the visuals a bit
  move-to new-location
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.