Diffuse Off Edges Example

patches-own
[
  value          ;; this is the quantity we will be diffusing
]

globals
[
  edge-patches   ;; border patches where value should remain 0
  main-patches   ;; patches not on the border
]

to setup
  clear-all
  ;; we assume that vertical and horizontal wrapping are both
  ;; off, so edge and corner patches have fewer than 8 neighbors
  set edge-patches patches with [count neighbors != 8]
  set main-patches patches with [count neighbors = 8]
  ;; create some random numbers to diffuse
  ask main-patches [ set value random-float 100 ]
  recolor
  reset-ticks
end 

to recolor
  ask patches
    [ set pcolor scale-color blue value 0 100 ]
end 

to go
  ;; first, do a normal diffuse
  diffuse value 1
  ;; now remove any of the value which has reached the edges
  ;; of the world
  ask edge-patches [ set value 0 ]
  recolor
  tick
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.